@ echo off
REM You will need to edit this for paths and names
set gdir=C:\Home\Gellmu\gellmu
set emacs_dir=C:\Local\emacs-20.5
set emacs_exe=C:\Local\emacs-20.5\bin\emacs.exe
REM
REM Edits below here should be relatively rare
REM
set EMACSLOADPATH=%emacs_dir%\site-lisp;%emacs_dir%\lisp;%emacs_dir%\leim
set EMACSDATA=%emacs_dir%\etc
set EMACSPATH=%emacs_dir%\bin
set EMACSLOCKDIR=%emacs_dir%\lock
set TERM=CMD
set HOME_SAVE=%HOME%
set HOME_EXISTS=yes
set HOME_DEFAULT=C:\HOME\
set HOME=
if "%HOME%" == "%HOME_SAVE%" set HOME_EXISTS=no
if "%HOME_EXISTS%" == "yes" set HOME=%HOME_SAVE%
if "%HOME_EXISTS%" == "no" set HOME=%HOME_DEFAULT%
REM Under Windows emacs seems to need a name for the "-l" argument
REM   that is not the name of something else in the current dir
set elisplib=%gdir%/wgellmu.elc
set gname=%1
if "%gname%" == "" goto usage
set fname="%gname%.glm"
if not exist "%gname%.glm" goto bail
"%emacs_exe%" -batch -l "%elisplib%" -f gellmu-xml "%gname%.glm"
if not exist "%gname%.xml" goto sgbail
goto exit

:usage
echo Usage: wg2x name (suffix .glm IMPLIED)
goto exit

:bail
echo wg2x: -- "%gname%" -- GELLMU file not found
goto exit

:sgbail
echo wg2x: -- "%gname%" -- No XML file.  Did emacs fail?
goto exit

:exit