* specify folder and file name for animated GIF file;
filename animout 'z:\pauline.gif';

* 
you can change the DELAY between frames 
in the GOPTIONS statement at
the bottom of the SAS code
you need not change any other statements

you can put your own text
in the DATALINES file in the 
first data step 

if the animated GIF stops during
playback, just add some 
more blank lines between
the various blocks of text

comments/suggestions:  msz03@albany.edu
;

title;
footnote;

filename txt temp;
filename lll dummy;

proc printto log=lll;
run;

data text;
infile datalines eof=done;
input text $50.;
text = quote(trim(text));
return;
done:
_n_ + (-1);
call symputx ('nobs',_n_);
stop;
datalines;
 
 
 
 
 
 
 
 
HI GERRY
HAVE NOT SEEN
YOUR NAME
ON SAS-L
IN QUITE
A WHILE
 
 
 



 
 
NOT SURE 
IF THIS WOULD
GENERATE
OOOHS AND AAAAHS
 



 
 
 
 
 
BUT I HAVE
USED IT TO 
BEGIN AND/OR
END SAS-RELATED
PRESENTATIONS









IT HAS ALSO
BEEN USED
TO END A 
MASTER'S THESIS
PRESENTATION
AND THANK
VARIOUS FACULTY
FOR THEIR
ASSISTANCE
 


 
 
 

 
*** WELCOME *** 

IT'S NICE TO
SEE YOU ALL HERE
TODAY







YOU WILL 
LEARN A BIT
ABOUT SOME
THINGS YOU
CAN DO 
WITH SAS 









YOU MIGHT NOT
HAVE THOUGHT 
THAT SOME 
WERE POSSIBLE









THIS ANIMATED
GIF FILE WAS
GENERATED
USING SAS/GRAPH







 
!!!  THANKS   !!!
!!!    FOR    !!!
!!! ATTENDING !!!






 
 
;
run;


data _null_;
file txt;
array txt(&nobs) $50 _temporary_;

do j=1 to &nobs;
   set text;
   txt(j) = text;
end;

put                         /
'proc catalog c=text kill;' /
'quit;'                     //
'ods results off;'          //

;

do j=1 to (&nobs - 9);
   l=j-1;

   do k=1 to 10;
      l+1;
      s=k+5;
      put 'footnote' k 'h=' s txt(l) ';';
   end;

   put
   "proc gslide gout=text name='txt" j +(-1) "';" /
   'run;'                                         /
   'quit;'                                        /
   ;
end;

put

'ods results off;' /
;
run;

goptions
reset=all
ftext=swiss
ctext=yellow
gunit=pct
device=gif
gsfname=nographics
;

filename nographics dummy;

%inc txt;

data _null_;
file txt;
put
'proc greplay igout=text  nofs;'              /
'tc work;'                                  /
'tdef four 1/llx=0   ulx=35  lrx=100 urx=65'  /
'            lly=5   uly=75  lry=5   ury=75;' /
'template four;'
;
put
'tplay 1:txt1 ; run;'      /
'goptions gsfmode=append;' /
;

do j=2 to (&nobs - 9);
   put 'tplay 1:txt' j '; run;' ;
end;

put
'quit; '/
'ods results; ' ;
run;

goptions
device=gifanim
xpixels=1000
ypixels=750
gsfname=animout
gsfmode=replace
iteration=0
delay=35
gepilog='3B'x
ctext=yellow
cback=black
;

%inc txt;

proc printto;
run;

filename txt;
filename lll;
filename animout;