* formatted input - organized data;

data x;
input
@01 name    $7.
@08 gender  $1.
@09 zip     $5.
@14 age      2.
;
datalines;
MIKE   M1220359
JESSICAF0213824
;
run;

title 'formatted input - organized data';
proc print data=x;
run;

* column input - organized data;

data x;
input
name    $  1-7
gender  $  8
zip     $  9-13
age       14-15
;
datalines;
MIKE   M1220359
JESSICAF0213824
;
run;

title 'column input - organized data';
proc print data=x;
run;

* formatted input - organized data, forget the periods on the informats;

data x;
input
@01 name    $7
@08 gender  $1
@09 zip     $5
@14 age      2
;
datalines;
MIKE   M1220359
JESSICAF0213824
;
run;

title 'formatted input - organized data, forget the periods on the informats';
proc print data=x;
run;

* list input - organized data + delimiter (space);

data x;
input
name   :  $7.
gender :  $1.
zip    :  $5.
age
;
datalines;
MIKE    M 12203 59
JESSICA F 02138 24
;
run;

title 'list - organized data + delimiter (space)';
proc print data=x;
run;

proc  contents data=x;
run;

* list input - organized data + delimiter (space);

data x;
input
name   $
gender $
zip    $
age
;
datalines;
MIKE    M 12203 59
JESSICA F 02138 24
;
run;

title 'list - organized data + delimiter (space)';
proc print data=x;
run;

proc  contents data=x;
run;

* list input - organized data + delimiter (space), forget the colon modifier;

data x;
input
name     $7.
gender   $1.
zip      $5.
age
;
datalines;
MIKE    M 12203 59
JESSICA F 02138 24
;
run;

title 'list input - organized data + delimiter (space), forget the colon modifier';
proc print data=x;
run;

* list input - unorganized data + delimiter (space);

data x;
input
name   :  $7.
gender :  $1.
zip    :  $5.
age
;
datalines;
MIKE M 12203 59
JESSICA F 02138 24
;
run;

title 'list input - unorganized data + delimiter (space)';
proc print data=x;
run;

* list input - unorganized data + delimiter (space), forget the colon modifier;

data x;
input
name     $7.
gender   $1.
zip      $5.
age
;
datalines;
MIKE M 12203 59
JESSICA F 02138 24
;
run;

title 'list input - unorganized data + delimiter (space), forget the colon modifier';
proc print data=x;
run;

* list input - unorganized data + delimiter (space), forget the colon modifier and periods;

data x;
input
name     $7
gender   $1
zip      $5
age
;
datalines;
MIKE M 12203 59
JESSICA F 02138 24
;
run;

title 'list input - unorganized data + delimiter (space), forget the colon modifier';
proc print data=x;
run;


* list input - unorganized data + delimiter (comma);

data x;
infile datalines dsd;
input
name   :  $7.
gender :  $1.
zip    :  $5.
age
;
datalines;
MIKE,M,12203,59
JESSICA,F,02138,24
;
run;

title 'list input - unorganized data + delimiter (comma)';
proc print data=x;
run;